/*
  Copyright (c) 2008, Adobe Systems Incorporated
  All rights reserved.

  Redistribution and use in source and binary forms, with or without 
  modification, are permitted provided that the following conditions are
  met:

  * Redistributions of source code must retain the above copyright notice, 
    this list of conditions and the following disclaimer.
  
  * Redistributions in binary form must reproduce the above copyright
    notice, this list of conditions and the following disclaimer in the 
    documentation and/or other materials provided with the distribution.
  
  * Neither the name of Adobe Systems Incorporated nor the names of its 
    contributors may be used to endorse or promote products derived from 
    this software without specific prior written permission.

  THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS
  IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO,
  THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR 
  CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
  PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
  LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
  NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
*/
package com.adobe.images
{
	import flash.events.Event;
	import flash.events.EventDispatcher;
	import flash.events.TimerEvent;
	import flash.geom.*;
	import flash.display.Bitmap;
	import flash.display.BitmapData;
	import flash.utils.ByteArray;
	import flash.utils.Timer;

	import flash.utils.getTimer;
	
	/**
	 * Class that converts BitmapData into a valid PNG
	 */	
	public class PNGEncoderAsync extends EventDispatcher
	{
		/**
		 * Created a PNG image from the specified BitmapData
		 *
		 * @param image The BitmapData that will be converted into the PNG format.
		 * @return a ByteArray representing the PNG encoded image data.
		 * @langversion ActionScript 3.0
		 * @playerversion Flash 9.0
		 * @tiptext
		 */
		
		public static const PROGRESS :String = "progress";
		public static const COMPLETE :String = "complete";
		
		
		private var _png :ByteArray;
		private var _img :BitmapData;
		private var _IDAT :ByteArray;
		
		private var _w :int;
		private var _h :int;
		private var _c :int;
		
		private var _fps :int;
		
		
		public function PNGEncoderAsync ( ) :void
		{
		}
		 
		public function encode ( img:BitmapData, frameRate :int = 30 ) :void {
	       
			_png = new ByteArray();
			_img = img;
			_fps = frameRate;
			
			// Write PNG signature
	        _png.writeUnsignedInt(0x89504e47);
	        _png.writeUnsignedInt(0x0D0A1A0A);
	        // Build IHDR chunk
	        var IHDR:ByteArray = new ByteArray();
	        IHDR.writeInt(_img.width);
	        IHDR.writeInt(_img.height);
	        IHDR.writeUnsignedInt(0x08060000); // 32bit RGBA
	        IHDR.writeByte(0);
	        writeChunk(_png,0x49484452,IHDR);
	        
			// Build IDAT chunk
			_IDAT = new ByteArray();
			
			_w = 0;
			_h = 0;
			_c = 0;
			
			trace("start");
			
			timerStart();
	    }
		private function onTimer ( evt :TimerEvent ) :void
		{
			var tt :int;
			var tn :int = getTimer();
			var interval :int = 1000 / _fps;
			
			LOOP: for ( var i:int=_h; i < _img.height; i++,_h++ ) {
	            
				// no filter
	            if ( _w == 0 )	_IDAT.writeByte(0);
	            
				var p:uint;
	            var j:int;
				
	            if ( !_img.transparent ) {
	                for ( j = _w; j < _img.width; j++, _w++ )
					{
	                    p = _img.getPixel(j,i);
	                    _IDAT.writeUnsignedInt( uint(((p & 0xFFFFFF) << 8) | 0xFF) );
						
						tt = getTimer() - tn;
						if ( interval < tt ) break LOOP;
	                }
	            } else {
	                for ( j = _w; j < _img.width; j++, _w++ )
					{
	                    p = _img.getPixel32(j,i);
	                    _IDAT.writeUnsignedInt( uint(((p & 0xFFFFFF) << 8) | (p >>> 24)) );
						
						tt = getTimer() - tn;
						if ( interval < tt ) break LOOP;
	                }
	            }
				_w = 0;
				_c ++;
	        }
			
			// --------------------------------- break
			j ++;
			_w ++;
			
			if ( _img.width <= j ) {
				_w = 0;
				_c ++;
				i ++;
				_h ++;
			}
			// ---------------------------------
			
			if ( _img.width <= j && _img.height <= i )
				buildIENDchunk();
			else
				timerStart( evt.target as Timer );
		}
		private function timerStart ( stopTimer :Timer = null ) :void
		{
			if ( stopTimer != null )
			{
				stopTimer.stop();
				stopTimer.removeEventListener(TimerEvent.TIMER, onTimer);
			}
			
			var t :Timer = new Timer(1,1);
			t.addEventListener(TimerEvent.TIMER, onTimer);
			t.start();
			
			dispatchEvent(new Event(PNGEncoderAsync.PROGRESS));
		}
		
		private function buildIENDchunk( ):void
		{
			trace("comp");
			
			_IDAT.compress();
			writeChunk(_png,0x49444154,_IDAT);	// Build IEND chunk
			writeChunk(_png,0x49454E44,null);
			
			_img.dispose();
			_img = null;
			dispatchEvent(new Event(PNGEncoderAsync.COMPLETE));
		}
		
	    private var crcTable:Array;
	    private var crcTableComputed:Boolean = false;
		
	    private function writeChunk(png:ByteArray, 
	            type:uint, data:ByteArray):void {
	        if (!crcTableComputed) {
	            crcTableComputed = true;
	            crcTable = [];
	            var c:uint;
	            for (var n:uint = 0; n < 256; n++) {
	                c = n;
	                for (var k:uint = 0; k < 8; k++) {
	                    if (c & 1) {
	                        c = uint(uint(0xedb88320) ^ 
	                            uint(c >>> 1));
	                    } else {
	                        c = uint(c >>> 1);
	                    }
	                }
	                crcTable[n] = c;
	            }
	        }
	        var len:uint = 0;
	        if (data != null) {
	            len = data.length;
	        }
	        png.writeUnsignedInt(len);
	        var p:uint = png.position;
	        png.writeUnsignedInt(type);
	        if ( data != null ) {
	            png.writeBytes(data);
	        }
	        var e:uint = png.position;
	        png.position = p;
	        c = 0xffffffff;
	        for (var i:int = 0; i < (e-p); i++) {
	            c = uint(crcTable[
	                (c ^ png.readUnsignedByte()) & 
	                uint(0xff)] ^ uint(c >>> 8));
	        }
	        c = uint(c^uint(0xffffffff));
	        png.position = e;
	        png.writeUnsignedInt(c);
	    }
		
		public function get total():Number
		{
			if ( _img )		return _img.width * _img.height;
			else			return -1;
		}
		public function get encoded():Number
		{
			if ( _img )		return _c * _img.width + _w;
			else			return -1;
		}
		
		public function get image():ByteArray { return _png; }
		
	}
}